#  Copyright (C) Cfengine AS

#  This file is part of Cfengine 3 - written and maintained by Cfengine AS.

#  This program is free software; you can redistribute it and/or modify it
#  under the terms of the GNU General Public License as published by the
#  Free Software Foundation; version 3.

#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA

# To the extent this program is licensed as part of the Enterprise
# versions of Cfengine, the applicable Commercial Open Source License
# (COSL) may apply to this file if you as a licensee so wish it. See
# included file COSL.txt.

########################################################
#
# Simple test copy from server connection to cfServer
#
########################################################

#
# run this as follows:
#
# cf-serverd -f runtest_1.cf [-d2]
# cf-agent   -f runtest_2.cf
#
# Notice that the same file configures all parts of cfengine

########################################################

body common control

{
      bundlesequence  => { "example" };
      version => "1.2.3";
}

########################################################

bundle agent example

{
  files:

      "/home/mark/tmp/test_to" 

      comment  => "test copy promise",
      copy_from    => mycopy("/home/mark/tmp/test_from","127.0.0.1"),
      perms        => system,
      depth_search => recurse("inf"),
      classes      => satisfied("copy_ok");

  reports:

    copy_ok::

      "Files were copied..";
}

#########################################################

body perms system

{
      mode  => "0644";
}

#########################################################

body depth_search recurse(d)

{
      depth => "$(d)";
}

#########################################################

body copy_from mycopy(from,server)

{
      source      => "$(from)";
      servers     => { "$(server)" };
      compare     => "digest";
      verify      => "true";
      copy_backup => "true";                  #/false/timestamp
      purge       => "true";
      type_check  => "true";
      force_ipv4  => "true";
      trustkey => "true";
}

#########################################################

body classes satisfied(x)
{
      promise_repaired => { "$(x)" };
      persist_time => "0";
}

#########################################################
# Server config
#########################################################

body server control 

{
      allowconnects         => { "127.0.0.1" , "::1" };
      allowallconnects      => { "127.0.0.1" , "::1" };
      trustkeysfrom         => { "127.0.0.1" , "::1" };
}

#########################################################

bundle server access_rules()

{
  access:

      "/home/mark/tmp"

      admit   => { "127.0.0.1" };
}
